Uniswap V2 Whitepaper 톺아보기

// 토큰A, 토큰B 주소를 받아서 새로운 페어 컨트랙트를 만드는 함수다.
function createPair(address tokenA, address tokenB) external returns (address pair) {
    require(tokenA != tokenB, 'UniswapV2: IDENTICAL_ADDRESSES');
    // 각 토큰의 어드레스 값의 크기 기준으로 순서를 만든다.
    (address token0, address token1) = tokenA < tokenB ? (tokenA, tokenB) : (tokenB, tokenA);
    require(token0 != address(0), 'UniswapV2: ZERO_ADDRESS');
    // 이미 페어가 있으면 실패시킨다.
    require(getPair[token0][token1] == address(0), 'UniswapV2: PAIR_EXISTS'); // single check is sufficient
            
    // 토큰 페어 컨트랙트 코드를 바이트코드로 가져온다
    bytes memory bytecode = type(UniswapV2Pair).creationCode;
    // token0과 token1의 ABI로 keccak256 해시함수를 돌려서 salt를 생성한다.
    bytes32 salt = keccak256(abi.encodePacked(token0, token1));
    assembly {
        pair := create2(0, add(bytecode, 32), mload(bytecode), salt)
    }
    // create2 함수로 페어 컨트랙트를 생성한다.
    IUniswapV2Pair(pair).initialize(token0, token1);
    // 생성한 토큰 페어 컨트랙트에 initialize 메소드에 token0, token1을 넣고 실행해준다.
    getPair[token0][token1] = pair;
    getPair[token1][token0] = pair; 
    // getPair에 페어 컨트랙트 주소 넣어준다.
    allPairs.push(pair);
    emit PairCreated(token0, token1, pair, allPairs.length);
    // 페어가 생성되었다는 로그를 남긴다.
}

// 페어 컨트랙트는 각 토큰 컨트랙트로부터 잔고 정보를 받아와 업데이트 해야 한다.
// 실제 잔고 정보는 token0, token1 컨트랙트에 저장되어 있다.
// 이 컨트랙트가 기록하고 있는 토큰의 양보다 각 토큰 컨트랙트의 실제 잔고가 많다면, 돈이 들어온 것으로 본다.
// update reserves and, on the first call per block, price accumulators
function _update(uint balance0, uint balance1, uint112 _reserve0, uint112 _reserve1) private {
    require(balance0 <= uint112(-1) && balance1 <= uint112(-1), 'UniswapV2: OVERFLOW');
    uint32 blockTimestamp = uint32(block.timestamp % 2**32);
    uint32 timeElapsed = blockTimestamp - blockTimestampLast; // overflow is desired
    // 유니스왑의 PRICE ORACLE 관련 코드다.
    if (timeElapsed > 0 && _reserve0 != 0 && _reserve1 != 0) {
        // * never overflows, and + overflow is desired
        price0CumulativeLast += uint(UQ112x112.encode(_reserve1).uqdiv(_reserve0)) * timeElapsed;
        price1CumulativeLast += uint(UQ112x112.encode(_reserve0).uqdiv(_reserve1)) * timeElapsed;
        // 각 가격이 유지된 시간의 가중치만큼을 곱해서 평균을 내어 가격을 결정한다.
        // price0CumulativeLast, price1CumulativeLast이 Price Oracle에 사용되는 변수이기 때문에 public 변수인 것이다.
    }
    reserve0 = uint112(balance0);
    reserve1 = uint112(balance1);
    // 잔고를 업데이트시킨다.
    blockTimestampLast = blockTimestamp;
    emit Sync(reserve0, reserve1);
}

// LP토큰(LP share)를 만들어내는 함수다.
// 페어 컨트랙트가 가지고 있는 자산의 양과 실제로 토큰 컨트랙트들에 기록되는 자산의 양이 다를 수 있다. 이걸 위에서 설명한 업데이트 함수가 토큰 잔액 정보를 가져오게 되는 것이다.
// 토큰 컨트랙트에 있는 자산의 양이 페어 컨트랙트가 기록해놓은 토큰 자산 양보다 더 많으면 mint가 된다.
// 토큰이 deposit된 것이기 때문에 유동성 공급자에게 LP를 mint해주는 것이다.
// 반대로 토큰 컨트랙트에 있는 자산의 양이 더 적으면 withdraw가 일어난 것이므로 burn이 일어난다.
// this low-level function should be called from a contract which performs important safety checks
function mint(address to) external lock returns (uint liquidity) {
    (uint112 _reserve0, uint112 _reserve1,) = getReserves(); // gas savings
    uint balance0 = IERC20(token0).balanceOf(address(this));
    uint balance1 = IERC20(token1).balanceOf(address(this));
    // 각 토큰 컨트랙트에서 잔고 정보를 받아온다.
    uint amount0 = balance0.sub(_reserve0);
    uint amount1 = balance1.sub(_reserve1);
    // reserve0, reserve1은 현재 페어 컨트랙트가 가지고 있는 잔고 정보다.
    // 즉, 새로운 잔액 정보에서 reserve를 빼주면 deposit된 금액 정보가 나온다.
            
    bool feeOn = _mintFee(_reserve0, _reserve1);
    // mintFee를 계산한다.
    uint _totalSupply = totalSupply; // gas savings, must be defined here since totalSupply can update in _mintFee
    if (_totalSupply == 0) {
        // 만약 처음 이 컨트랙트에 풀을 공급하는 사람이라면
        // 보호장치로써 LP토큰이 일부 burn된다. (앞에서 설명한 내용)
        liquidity = Math.sqrt(amount0.mul(amount1)).sub(MINIMUM_LIQUIDITY);
        // 처음 풀에 유동성을 공급할 때 일부 burn된다고 했던 양이 MINIMUM_LIQUIDITY만큼이다.
        _mint(address(0), MINIMUM_LIQUIDITY); // permanently lock the first 
        MINIMUM_LIQUIDITY tokens
        // MINIMUM_LIQUIDITY만큼의 LP토큰은 0번 주소에 mint해서 burn해버린다.
    } else {
        // 이미 풀에 유동성이 존재한다면, 앞에서 설명한 1번 공식대로 LP토큰의 mint 양이 정해진다.
        liquidity = Math.min(amount0.mul(_totalSupply) / _reserve0, amount1.mul(_totalSupply) / _reserve1);
    }
    require(liquidity > 0, 'UniswapV2: INSUFFICIENT_LIQUIDITY_MINTED');
    _mint(to, liquidity); // deposit한 유동성 공급자에게 LP토큰을 mint해준다.

    _update(balance0, balance1, _reserve0, _reserve1);
    if (feeOn) kLast = uint(reserve0).mul(reserve1); // reserve0 and reserve1 are up-to-date
    // 유동성이 양쪽 토큰에 공급되었으므로, x*y=k의 k값을 새로 업데이트 해준다.
    emit Mint(msg.sender, amount0, amount1);
    // 민트 이벤트 로그를 남긴다.
}

function burn(address to) external lock returns (uint amount0, uint amount1) {
    ... // 생략
    
    // LP 토큰을 burn시킨다.
    _burn(address(this), liquidity);
    // 소각한 LP토큰만큼의 양에 해당하는 유동성을 다시 돌려준다.
    _safeTransfer(_token0, to, amount0);
    _safeTransfer(_token1, to, amount1);
    balance0 = IERC20(_token0).balanceOf(address(this));
    balance1 = IERC20(_token1).balanceOf(address(this));

    // 토큰 잔고를 업데이트한다.
    _update(balance0, balance1, _reserve0, _reserve1);
    if (feeOn) kLast = uint(reserve0).mul(reserve1); // reserve0 and reserve1 are up-to-date
    // 유동성 풀의 크기가 변동되었으므로 x*y=k의 k값을 새로 업데이트 해준다.
    emit Burn(msg.sender, amount0, amount1, to);
    // 번 이벤트 로그를 남긴다.
}